comment {
  drd.ufm 1.1
  Fractal formulae for Ultra Fractal
  (originally written by me for FractInt,
   some years ago, and here converted to UF)
  by Daniel Dockery
  ultrafrac@peritus.virtualave.net
  November 22, 2001
 }

pseudobrot_generalized {
  init:
    z = #pixel
    v = #pixel
    c = #pixel
  loop:
    d = v^2/c^2
    z = fn1(fn2(1-d))
    v = #pixel
    c = d^z
  bailout:
    |z| <= 4
  default:
    title = "pseudobrot_generalized"
    method = multipass
    maxiter = 100
    func fn2
      caption = "Primary function"
      hint = "This is the first function applied"
      default = sqrt()
    endfunc
    func fn1
      caption = "Secondary function"
      hint = "This is the second function applied"
      default = sqr()
    endfunc
 }

Wave {
  init:
    z = #pixel
  loop:
    f = #pixel
    z = p1 * fn1(2*#pi*f*z)
  bailout:
    |z| <= 10
  default:
    title = "Wave"
    func fn1
      caption = "Variable Function"
      default = sin()
    endfunc
    param p1
      caption = "Control parameter"
      hint = "Increase or decrease this value\
              to vary the fractal.\
              Value should be non-zero."
      default = (1.0, 0.0)
    endparam
 }

Nine {
  init:
    z = #pixel
  loop:
    c = 1.39 * #pixel
    z = z^9 + (9/c)
  bailout:
    .0001 <= z
  default:
    title = "Nine"
    method = multipass
 }

Nine2 {
  init:
    z = #pixel
  loop:
    c = 1.39 * #pixel
    z = z^9 + (9/c)
  bailout:
    .0001 <= (z^9 + (9/c))
  default:
    title = "Nine2"
    method = multipass
 }

m4f {
  init:
    l = #pixel
    z = (1.0,0.0)
    d = (1.0,0.0)
    oz = 1.0/z
  loop:
    z = l * (z + oz)
    oz = 1.0/z
    z = l * (z + oz)
    oz = 1.0/z
    t = 1 - oz/z
    l = #pixel
    al = |l|
    d = d * al * |t|
  bailout:
    |d| < 100
  default:
    title = "m4f"
    method = multipass
 }

nov2 {
  init:
    z = #pixel
  loop:
    c = fn1(#pixel)
    z = fn1(z)
    zz = z^z
    z3 = z^3
    z = 1/fn2(zz + z3 + c)
  bailout:
    |z| <= 4
  default:
    title = "nov2"
    method = multipass
    func fn1
      caption = "Variable Function"
      default = conj()
    endfunc
    func fn2
      caption = "Variable Function"
      default = ident()
    endfunc
 }

eis {
  init:
    z = #pixel
    ct = #pixel
    l = #pixel
  loop:
    l = l / z + #pixel
    a = (l + #pixel)/2
    b = (l - #pixel)/2
    z = a*z - b*ct
    ct = a*ct - b*z
  bailout:
    |z| <= 50
  default:
    title = "eis"
    method = multipass
 }

cseven {
  init:
    z = #pixel
  loop:
    z = z * (z+1) * (2*z+1) / #pixel
  bailout:
    |z| <= 100
  default:
    title = "cseven"
    method = multipass
 }