Barnsley_PHC_3 {; formula adapted by Vincent Damion Presogna
                ; SOURCE: 96msg.frm
                ; modified for UF multi-layer cabability by
                ; Erik Reckase, January 2000
init:
  z = c = pixel
  IF (@p3==1)
    c1 = @p1, c2 = 0
  ELSEIF (@p3==0)
    c1 = c, c2 = @p2
  ELSE
    IF (whitesq)
      c1 = @p1, c2 = 0
    ELSE
      c1 = c, c2 = @p2
    ENDIF
  ENDIF
loop:
  IF (z>=0)
    z1 = z - 1
  ELSE
    z1 = z + 1
  ENDIF
  z = z1*c1 + c2
bailout:
  |z| < 4
default:
  title = "Barsley PHC 3"
  param p1
    caption = "Parameter 1"
    default = (0,0)
  endparam
  param p2
    caption = "Parameter 2"
    default = (0,0)
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
    endparam
}

LesPHCfrm04 {; Les St Clair [101461,2032], 1996
             ; Based on Liar1 & Glynn formulas by 
             ; Chuck Ebbert and Earl Glynn 
             ; SOURCE: 96msg.frm
             ; modified for UF multi-layer cabability by
             ; Erik Reckase, January 2000
init:            
  z = pixel
  IF (@p3==1)
    bail = 4
  ELSEIF (@p3==0)
    bail = 1
  ELSE
    IF (whitesq)
      bail = 4
    ELSE
      bail = 1
    ENDIF
  ENDIF
loop:
  IF (@p3==1)
    z = (z ^ p1 - p2)
  ELSEIF (@p3==0)
    z = (1 - abs(imag(z)-real(z)) + flip(1 - abs(1-real(z)-imag(z))))
  ELSE
    IF (whitesq)
      z = (z ^ p1 - p2)
    ELSE
      z = (1 - abs(imag(z)-real(z)) + flip(1 - abs(1-real(z)-imag(z))))
    ENDIF
  ENDIF
bailout:
  |z| <= bail
default:
  title = "LesPHCfrm04"
  param p1
    caption = "Parameter 1"
    default = (0,0)
  endparam
  param p2
    caption = "Parameter 2"
    default = (0,0)
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
    endparam
}

Gallet-4-04 {; Sylvie Gallet [101324,3444], 1996
             ; PHC formula
             ; modified for UF multi-layer capability by
             ; Erik Reckase, March 2000
init:
  if (@p3==1)
    z = pixel
  elseif (@p3==0)
    z = 1/pixel
  else
    if whitesq
      z = pixel
    else
      z = 1/pixel
    endif
  endif  
loop:
  x = real(z), y = imag(z)
  x1 = x - p1 * fn1(y + p2*fn2(y))
  y1 = y - p1 * fn1(x + p2*fn2(x))
  z = x1 + flip(y1)
bailout:
  |z| <= 4
default:
  title="Gallet-4-04"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass  
  param p1
    caption = "Parameter 1"
    default = (10,0)
  endparam
  param p2
    caption = "Parameter 2"
    default = (1,.2)
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1,2 are the 2 separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
  func fn1
    caption = "Function 1"
    default = tan()
  endfunc
  func fn2
    caption = "Function 2"
    default = sin()
  endfunc
}

Gallet-4-05 {; Sylvie Gallet [101324,3444], 1996
             ; PHC formula
             ; modified for UF multi-layer capability by
             ; Erik Reckase, March 2000
init:
  z = pixel
loop:
  x = real(z), y = imag(z)
  if (@p3==1)
    x1 = x - p1 * fn1(y*(y - 1) + p2*fn2(y))
    y1 = y - p1 * fn1(x^2 + p2*fn2(x))
  elseif (@p3==0)
    x1 = x - p1 * fn1(y^2 + p2*fn2(y))
    y1 = y - p1 * fn1(x*(x - 1) + p2*fn2(x))
  else
    if whitesq
      x1 = x - p1 * fn1(y*(y - 1) + p2*fn2(y))
      y1 = y - p1 * fn1(x^2 + p2*fn2(x))
    else
      x1 = x - p1 * fn1(y^2 + p2*fn2(y))
      y1 = y - p1 * fn1(x*(x - 1) + p2*fn2(x))
    endif
  endif
  z = x1 + flip(y1)
bailout:
  |z| <= 4
default:
  title="Gallet-4-05"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass  
  param p1
    caption = "Parameter 1"
    default = (10,0)
  endparam
  param p2
    caption = "Parameter 2"
    default = (1,.2)
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1,2 are the 2 separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
  func fn1
    caption = "Function 1"
    default = tan()
  endfunc
  func fn2
    caption = "Function 2"
    default = sin()
  endfunc
}

Gallet-4-06 {; Sylvie Gallet [101324,3444], 1996
             ; PTC formula
             ; SOURCE: gallet-4.frm
             ; modified for UF multi-layer capability by
             ; Erik Reckase, January 2000
init:
  sq3 = -0.5 + flip(sqrt(3)/2)
  IF (@p3==2)
    c = 1
  ELSEIF (@p3==1)
    c = sq3
  ELSEIF (@p3==0)
    c = conj(sq3)
  ELSE
    cr = real(scrnpix) + imag(scrnpix)
    r = cr - 3 * trunc(cr / real(3))
    IF (r==0)
      c = 1
    ELSEIF (r==1)
      c = sq3
    ELSE
      c = conj(sq3)
    ENDIF
  ENDIF
  z = c * pixel 
loop:
   x = real(z), y = imag(z)
   x1 = x - p1 * fn1(y*y + p2*fn2(y))
   y1 = y - p1 * fn1(x*x + p2*fn2(x))
   z = x1 + flip(y1)
bailout:
    |z| <= 4
default:
  title = "Gallet-4-06"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass  
  param p1
    caption = "Parameter 1"
    default = (0,0)
  endparam
  param p2
    caption = "Parameter 2"
    default = (0,0)
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Option 3" "Original"
    default = 3
    hint = "Options 1,2,3 are the 3 separate layers of this \
            formula.  The 'Original' option uses the original \
            PTC formula."
  endparam
  func fn1
    caption = "Function 1"
  endfunc
  func fn2
    caption = "Function 2"
  endfunc
}

Gallet-4-07 {; Sylvie Gallet [101324,3444], 1996
             ; PHC formula
             ; SOURCE: gallet-4.frm
             ; modified for UF multi-layer capability by
             ; Erik Reckase, January 2000
init:
  z = 10 * pixel, float bailout = real(p3)
  IF (@p4==1)
    c = p1
  ELSEIF (@p4==0)
    c = p1*(0,1)
  ELSE
    IF (whitesq)
      c = p1
    ELSE
      c = p1*(0,1)
    ENDIF
  ENDIF
loop:
  bool test = (real(flip(c*z)) >= 0)
  IF (test)
    z = (z-p2)*c
  ELSE
    z = (z+p2)*c
  ENDIF
bailout:
  abs(real(z)) < bailout || abs(imag(z)) < bailout
default:
  title = "Gallet-4-07"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Init. C"
    default = (0,0)
  endparam
  param p2
    caption = "Z Diff"
    default = (0,0)
  endparam
  param p3
    caption = "Bailout"
    default = (0,0)
    hint = "The real part of this parameter controls the bailout \
            value.  The imaginary part remains for backwards \
            Fractint compatibility."
  endparam
  param p4
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

Gallet-4-08 {; Sylvie Gallet [101324,3444], 1996
             ; PHC formula
             ; modified for UF multi-layer capability by
             ; Erik Reckase, March 2000
init:
  if (@p4==1)
    z = pixel
  elseif (@p4==0)
    z = -pixel
  else
    if whitesq
      z = pixel
    else
      z = -pixel
    endif
  endif
  c = p1, bailout = real(p3) 
loop:
  bool test = (flip(z*(c-z)) >= 0)
  if test
    z = (z-p2)*c
  else
    z = (z+p2)*c
  endif
bailout:
  (abs(real(z)) < bailout) || (abs(imag(z)) < bailout)
default:
  title = "Gallet-4-08"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Init. C"
    default = (0,0)
  endparam
  param p2
    caption = "Z Diff"
    default = (0,0)
  endparam
  param p3
    caption = "Bailout"
    default = (0,0)
    hint = "The real part of this parameter controls the bailout \
            value.  The imaginary part remains for backwards \
            Fractint compatibility."
  endparam
  param p4
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

Gallet-4-10 {; Sylvie Gallet [101324,3444], 1996
             ; PHC formula
             ; modified for UF multi-layer capability by
             ; Erik Reckase, March 2000
init:
  if (@p4==1)
    p = -p1
  elseif (@p4==0)
    p = (0,-1)*p1
  else
    if whitesq
      p = -p1
    else
      p = (0,-1)*p1
    endif
  endif
  a = pixel + p, b = pixel - p
  a1 = b1 = 0, a2 = 3*a*a, b2 = 3*b*b
loop:
  a = a^3 - a2*a + a1, b = b^3 - b2*b + b1
  a1 = a1 + p2, b1 = b1 + p2
  z = (a + b)/2
bailout:
  |z| <= p3
default:
  title = "Gallet-4-10"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "P Seed"
    default = (0,0)
  endparam
  param p2
    caption = "Add to"
    default = (0,0)
  endparam
  param p3
    caption = "Bailout"
    default = (0,0)
    hint = "The real part of this parameter controls the bailout \
            value.  The imaginary part remains for backwards \
            Fractint compatibility."
  endparam
  param p4
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

Gallet-4-12 {; Sylvie Gallet [101324,3444], 1996
             ; PHC formula
             ; modified for UF multi-layer capability by
             ; Erik Reckase, March 2000
init:
  if (@p4==1)
    p = -p1
  elseif (@p4==0)
    p = (0,-1)*p1
  else
    if whitesq
      p = -p1
    else
      p = (0,-1)*p1
    endif
  endif
  a = pixel + p, b = pixel - p, c = p2/pixel
  a1 = b1 = 0, a2 = 3*a*a, b2 = 3*b*b 
loop:
  a = a^3 - a2*a + a1, b = b^3 - b2*b + b1
  a1 = a1 + c, b1 = b1 + c
  z = (a + b)/2
bailout:
  |z| <= p3
default:
  title = "Gallet-4-12"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "P Seed"
    default = (0,0)
  endparam
  param p2
    caption = "Add to"
    default = (0,0)
  endparam
  param p3
    caption = "Bailout"
    default = (0,0)
    hint = "The real part of this parameter controls the bailout \
            value.  The imaginary part remains for backwards \
            Fractint compatibility."
  endparam
  param p4
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

Gallet-5-09 {; Sylvie Gallet [101324,3444], 1996
             ; PHC formula
             ; modified for UF multi-layer capability by
             ; Erik Reckase, March 2000
init:
  if (@p3==1)
    z = pixel
  elseif (@p3==0)
    z = -pixel/2
  else
    if whitesq
      z = pixel
    else
      z = -pixel/2
    endif
  endif
loop:
  x = real(z), y = imag(z)
  x1 = x - p1 * fn1(y + p2*fn2(y))
  y1 = y - p1 * fn1(x + p2*fn2(x))
  z = x1 + flip(y1)
bailout:
  |z| <= 64
default:
  title="Gallet-5-09"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass  
  param p1
    caption = "Parameter 1"
    default = (10,0)
  endparam
  param p2
    caption = "Parameter 2"
    default = (1,.2)
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1,2 are the 2 separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
  func fn1
    caption = "Function 1"
    default = tan()
  endfunc
  func fn2
    caption = "Function 2"
    default = sin()
  endfunc
}

SpecC-mod (XAXIS_NOPARM) {; modified for if..else by George Martin 3/18/97
                      ; Modified to support LHS 'Depth.par' ENR 3/22/2000
init:
   z = @p1
loop:
   IF (|z|>1)
      z = fn1(z)+pixel
   ENDIF
   z = conj(fn2(z))+pixel
bailout:
   |z| <= 4
}

JDfrm010 {; Jim Deutch [104074,3171], 1996.  The Original PHC formula
          ; Modified for UF by Erik Reckase, March 2000
init:
  z = 0
  if (@p1==1)
    c = pixel
  elseif (@p1==0)
    c = -pixel
  else
    if whitesq
      c = pixel
    else
      c = -pixel
    endif
  endif
loop:
  z = z*z + c
bailout:
  |z| < 4
default:
  title = "JDfrm010"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

JD-LS0 {; Lee Skinner [75450,3631], 1996  Requires passes=1
        ; Eliminated assignment to "pixel". G. Martin 6/29/99
        ; Modified for UF by Erik Reckase, March 2000
init:
  f1 = sin(pixel/2), f2 = 1/pixel
  if (@p1==1)
    c = f1
  elseif (@p1==0)
    c = f2
  else
    if whitesq
      c = f1
    else
      c = f2
    endif
  endif
  z = 0
loop:
  z = z*z + c
bailout:
  |z| < 4
default:
  title = "JD-LS0"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

JD-SG-01 {; Sylvie Gallet [101324,3444], 1996
          ; Mandel: z^(p1+1) + c , inverted Newton: z^p1 - 1 = 0
          ; use p2 to adjust the size of the inverted Newton set
          ; Modified for UF by Erik Reckase, March 2000
init:
  if (@p3==1)
    z=pixel
  elseif (@p3==0)
    z=@p2/(pixel-@p2)+1
  else
    if whitesq
      z=pixel
    else
      z=@p2/(pixel-@p2)+1
    endif
  endif
  c=pixel, float b1=256, float b2=.000001, ex=@p1-1
loop:
  zd = z^ex , zn = zd*z , n = zn - 1 , d =@p1*zd
  zo = zn*z + c , ze = z - n/d
  if (@p3==1)
    z = zo
    float zfinal = |z|
    float bfinal = b1
  elseif (@p3==0)
    z = ze
    float zfinal = b2
    float bfinal = |n|
  else
    if whitesq
      z = zo
      float zfinal = |z|
      float bfinal = b1
    else
      z = ze
      float zfinal = b2
      float bfinal = |n|
    endif
  endif
bailout:
  zfinal <= bfinal
default:
  title = "JD-SG-01"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Exponent"
    default = (6,0)
    hint = "Controls exponent of Mandel and Inv. Newton"
  endparam
  param p2
    caption = "N-Scale"
    default = (2,0)
    hint = "Scales Inv. Newton set"
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

JD-SG-02 {; Sylvie Gallet [101324,3444], 1996
          ; Mandel: z^2 + c, inverted Newton: z^p1 - 1 = 0
          ; use p2 to adjust the size of the inverted Newton set
          ; Modified for UF by Erik Reckase, March 2000
init:
  if (@p3==1)
    z=pixel
  elseif (@p3==0)
    z=@p2/(pixel-@p2)+1
  else
    if whitesq
      z=pixel
    else
      z=@p2/(pixel-@p2)+1
    endif
  endif
  c=pixel, float b1=256, float b2=.000001, ex=@p1-1
loop:
  zd = z^ex, zn = zd*z, n = zn - 1, d = p1 * zd
  zo = z*z + c, ze = z - n/d
  if (@p3==1)
    z = zo
    float zfinal = |z|
    float bfinal = b1
  elseif (@p3==0)
    z = ze
    float zfinal = b2
    float bfinal = |n|
  else
    if whitesq
      z = zo
      float zfinal = |z|
      float bfinal = b1
    else
      z = ze
      float zfinal = b2
      float bfinal = |n|
    endif
  endif
bailout:
  zfinal <= bfinal
default:
  title = "JD-SG-02"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Exponent"
    default = (6,0)
    hint = "Controls exponent of Mandel and Inv. Newton"
  endparam
  param p2
    caption = "N-Scale"
    default = (2,0)
    hint = "Scales Inv. Newton set"
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

JD-SG-03 {; Sylvie Gallet [101324,3444], 1996
          ; Mandel: z^(p1+1) + c , Newton: z^p1 - 1 = 0
          ; use p2 to adjust the size of the inverted Newton set
          ; Modified for UF by Erik Reckase, March 2000
init:
  z=c=pixel, float b1=256, float b2=.000001, ex=@p1-1
loop:
  zd = z^ex, zn = zd*z, n = zn - 1, d = @p1*zd
  zo = zn*z + c, ze = z - n/d
  if (@p3==1)
    z = zo
    float zfinal = |z|
    float bfinal = b1
  elseif (@p3==0)
    z = ze
    float zfinal = b2
    float bfinal = |n|
  else
    if whitesq
      z = zo
      float zfinal = |z|
      float bfinal = b1
    else
      z = ze
      float zfinal = b2
      float bfinal = |n|
    endif
  endif
bailout:
  zfinal <= bfinal
default:
  title = "JD-SG-03"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Exponent"
    default = (6,0)
    hint = "Controls exponent of Mandel and Inv. Newton"
  endparam
  param p2
    caption = "N-Scale"
    default = (2,0)
    hint = "Scales Inv. Newton set"
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

JD-SG-04 {; Sylvie Gallet [101324,3444], 1996
          ; use p1 and p2 to adjust the inverted Mandel
          ; modified for UF multi-layer capability by
          ;   Erik Reckase, March 2000
init:
  IF (@p3==1)
    z=c = pixel
  ELSEIF (@p3==0)
    z=c = @p1/(pixel + @p2)
  ELSE
    IF (whitesq)
      z=c = pixel
    ELSE
      z=c = @p1/(pixel + @p2)
    ENDIF
  ENDIF
loop:
  z = z*z + c
bailout:
  |z| < 4
default:
  title = "JD-SG-04"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "2nd Mandel Scalar"
    default = (-1,0)
    hint = "Controls the rotation and scale of the second \
            mandel. If multi-layer ,only affects Layer Option '1'"
  endparam
  param p2
    caption = "2nd Mandel Const"
    default = (0,0)
    hint = "Controls the X/Y position of the second mandel. \
            If multi-layer, only affects Layer Option '1'"
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}


JD-SG-05 {; Sylvie Gallet [101324,3444], 1996
          ; use p1 and p2 to adjust the 2nd Mandel
          ; Modified for IF..ELSE logic by Sylvie Gallet, 05/15/97
          ; modified for UF multi-layer capability by
          ;   Erik Reckase, March 2000
init:
  z = 0
  IF (@p3==1)
    c = pixel
  ELSEIF (@p3==0)
    c = @p1*pixel + @p2
  ELSE
    IF (whitesq)
      c = pixel
    ELSE
      c = @p1*pixel + @p2
    ENDIF
  ENDIF
loop:
  z = z*z + c
bailout:
  |z| < 4
default:
  title = "JD-SG-05"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "2nd Mandel Scalar"
    default = (-1,0)
    hint = "Controls the rotation and scale of the second \
            mandel. If multi-layer ,only affects Layer Option '1'"
  endparam
  param p2
    caption = "2nd Mandel Const"
    default = (0,0)
    hint = "Controls the X/Y position of the second mandel. \
            If multi-layer, only affects Layer Option '1'"
  endparam
  param p3
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

JD-SG-06 {; Sylvie Gallet [101324,3444], 1996
init:
  IF (@p2==1)
    z = real(p1)
  ELSEIF (@p2==0)
    z = flip(imag(p1))
  ELSE
    IF (whitesq)
      z = real(p1)
    ELSE
      z = flip(imag(p1))
    ENDIF
  ENDIF
loop:
  z = z*z + pixel
bailout:
  |z| < 4
default:
  title = "JD-SG-06"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (-.5,0)
  method = multipass
  param p1
    caption = "Z_initial"
    default = (.5,.3)
    hint = "Controls the initial value of z for each layer. \
            Layer Option 1 uses z = real(Z_initial), Layer \
            Option 2 uses z = flip(imag(Z_initial)."
  endparam
  param p2
    caption = "Layer Option"
    enum = "Option 1" "Option 2" "Original"
    default = 2
    hint = "Options 1 and 2 are the two separate layers of this \
            formula.  The 'Original' option uses the original \
            PHC formula."
  endparam
}

manjul_lace { ; George Martin, 1996
              ; Modified for IF..ELSE logic by Sylvie Gallet, March 1997
init:
   IF (@p1==1)
      z=c=1.5*pixel
   ELSEIF (@p1==2)
      z=pixel , c =(-.75,.1234567)
   ELSE
     IF whitesq
       z=c=1.5*pixel
     ELSE
       z=pixel,c=(-.75,.1234567)
     ENDIF
   ENDIF
loop:
   z = z*z + c
bailout:
   |z| <= 4
default:
  title = "manjul_lace"
  periodicity = 0
  maxiter = 500
  magn = 1
  center = (0,0)
  method = multipass
  param p1
    caption = "Layer Option"
    enum = "Original" "Mandel" "Julia"
    default = 0
    hint = "'Original' is the original PHC.  'Mandel' and 'Julia' \
            are the individual layers of the image."
  endparam
}