comment {
  Name:
    pwc-convert.ufm
  
  Version:
    1.2

  Description:
    Ultra Fractal conversions of Paul Carlson's fractal formulas.
  
  Author:
    Ken Childress - 1999, 2000
  
  Last Modification: 
    27 January 2000

  History:  
    Version 1.0 - Initial Release & Numerous Updates
    Version 1.1 - Added Phoenix_Mandel-bare
                  Added Popcorn-bare
                  Added bailout parameter to Zf_Ang-bare
                  Added NspirMset-bare
    Version 1.2 - Added Newt3_Mset-bare
                  Added Mod2_Pokorny_Mandel-bare
                  Added Pky2M2-bare
                  Added MyEqn_Mandel-bare
                  Added CZCubedMandel-bare
                  Added MsetModJulia-bare
                  Added IExpM2-bare
                  Added Celtic_Mandel-bare
                  Added CnFrc_Fnc_Julia-bare
                  Changed bailout values on Pokorny formulas to 4.0
}

Mod_Phoenix_Q-bare {
init:
  complex temp = 0
  complex y = #pixel
  #z = #pixel
  
loop:
  #z = #z^3 - #z^2 - 0.5*#z + @JuliaCoords
  temp = #z
  #z = #z^2 - 0.5*y + @JuliaCoords
  y = temp
  
bailout:
  |#z| < @MaxZsqd
  
default:
    title = "Mod_Phoenix_Q-bare"

    param JuliaCoords
    caption = "Julia Coordinates"
    default = (-0.55,0)
    hint = "The Julia set coordinates."
    endparam

    param MaxZsqd
    caption = "Maximum |z|"
    default = 100
    hint = "Maximum |z| for bailout."
    endparam
}

CshSnM2-bare {
  ; Original formula, CshSnM2, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Damien Jones.
  ; Modified further by Ken Childress.
  ; 18 May 1999
init:
  z = 0
  
loop:
  z = cosh(z) + #pixel
  z = sin(z) + #pixel

bailout:
  |z| < @bailout

default:
  title = "Cosh Sin Mset"
  maxiter = 500

  param bailout
    caption = "Bailout"
    default = 1.0e100
    hint = "A very high value is needed to capture detail."
  endparam
}

CosCosM2-bare {
  ; Original formula, CshSnM2, by Paul Carlson.
  ; Modified to be Cos - Cos by Ken Childress.
  ; 23 May 1999
init:
  z = 0
  
loop:
  z = cos(z) + #pixel
  z = cos(z) + #pixel

bailout:
  |z| < @bailout

default:
  title = "Cos Cos Mset"
  maxiter = 500

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high bailout value is needed to capture detail."
  endparam
}

CosSinhM2-bare {
  ; Original formula, CshSnM2, by Paul Carlson.
  ; Modified to be cos, sinh by Ken Childress.
  ; 18 May 1999
  ; This one does not reproduce the detail that the original
  ; formula CshSnM2 modifed to be CosSinh will produce.  I don't
  ; know why.
init:
  z = 0
  
loop:
  z = cos(z) + #pixel
  z = sinh(z) + #pixel

bailout:
  |z| < @bailout

default:
  title = "Cos Sinh Mset"
  maxiter = 500

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high bailout value is needed to capture detail."
  endparam
}

CoshTan-bare {
  ; Original formula, Cosh_Tan_Mset, by Paul Carlson.
  ; Modified to be cos, sinh by Ken Childress.
  ; 04 June 1999
init:
  z = 0
  
loop:
  z = cosh(tan(z)) + #pixel

bailout:
  |z| < @bailout

default:
  title = "Cosh Tan Mset"
  maxiter = 1000

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high bailout value is needed to capture detail."
  endparam
}

Sin_Julia-bare {
  ; Original formula, Sin_Atan_Julia, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 22 May 1999
init:
  z = #pixel
  
loop:
  z = sin(z) + @JuliaCoords

bailout:
  |z| < @bailout

default:
  title = "Sin Julia"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-1.1684406885759,-0.8606881002087681)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high bailout value is needed to capture detail."
  endparam
}

Sin_Mandel-bare {
  ; Original formula, Sin_Atan_Julia, by Paul Carlson.
  ; Modified for Mandel formula by Ken Childress.
  ; 25 January 2000
init:
  z = 0
  
loop:
  z = sin(z) + #pixel

bailout:
  |z| < @bailout

default:
  title = "Sin Mandel"
  maxiter = 1000

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high bailout value is needed to capture detail."
  endparam
  
switch:
  type = "Sin_Julia-bare"
  bailout = @bailout
  JuliaCoords = #pixel
}

Cos_Julia-bare {
  ; Original formula, Sin_Atan_Julia, by Paul Carlson.
  ; Modified to be Cos by Ken Childress.
  ; 22 May 1999
init:
  z = #pixel
  
loop:
  z = cos(z) + @JuliaCoords

bailout:
  |z| < @bailout
  
default:
  title = "Cos Julia"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-1.1684406885759,-0.8606881002087681)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high value is needed to capture detail."
  endparam
}

Cos_Squared_Julia-bare {
  ; Original formula, Sin_Atan_Julia, by Paul Carlson.
  ; Modified to be Cos^2 by Ken Childress.
  ; 22 May 1999
init:
  z = #pixel
  
loop:
  z = cos(z) * cos(z) + @JuliaCoords

bailout:
  |z| < @bailout
  
default:
  title = "Cos Squared Julia"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-1.1684406885759,-0.8606881002087681)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high value is needed to capture detail."
  endparam
}

Log_Series_Mset-bare {
  ; Original formula, Log_Series_Mset, by Paul Carlson
  ; Modifed to remove coloring parts by Ken Childress.
  ; 19 May 1999
init:
  z = 0

loop:
  complex z2=z*z
  complex z4=z2*z2
  complex z6=z2*z4
  complex z8=z4*z4
  complex z10=z6*z4
  complex z12=z6*z6

  ;The series we're iterating
  z = z2 - z4/2 + z6/3 - z8/4 + z10/5 - z12/6 + #pixel

bailout:
  |z| < @bailout

default:
  title = "Log Series Mset"
  maxiter = 1000

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "A very high value is needed to capture detail."
  endparam
}

Curry_Mset-bare {
  ; Original formula, Curry_Rings_Mset, by Paul Carlson
  ; Modifed to remove coloring parts by Ken Childress.
  ; 15 June 1999
init:
  complex c = #pixel
  z = 0

loop:
  complex a = @Relax * (z^3 + (c - 1) * z - c) / (3 * z^2 + c - 1)
  z = z - a

bailout:
  |a| > @error && |z| < @bailout

default:
  title = "Curry Mset"
  maxiter = 1000
  
  param Relax
    caption = "Relaxation factor"
    default = 1.0
    hint = "Relaxation factor."
  endparam

  param error
    caption = "Error Value"
    default = 0.000001
    hint = "The error value."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "A very high value is needed to capture detail."
  endparam
}

MsetMod-bare {
  ; Original formula, Mset_Rings, by Paul Carlson
  ; Modifed to remove coloring parts by Ken Childress.
  ; 15 June 1999
init:
  complex c = #pixel
  z = 0

loop:
  z = (z^3 - z^2 - z^2 - 1) / (c - 1) + c

bailout:
  |z| < @bailout

default:
  title = "Mset Mod"
  maxiter = 5000
  
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "A very high value is needed to capture detail."
  endparam
  
switch:
  type = "MsetModJulia-bare"
  bailout = @bailout
  JuliaCoords = #pixel
}

MsetModJulia-bare {
  ; Original formula, Mset_Rings, by Paul Carlson
  ; Modifed for Julia formula by Ken Childress.
  ; 25 January 2000
init:
  complex c = @JuliaCoords
  z = #pixel

loop:
  z = (z^3 - z^2 - z^2 - 1) / (c - 1) + c

bailout:
  |z| < @bailout

default:
  title = "Mset Mod Julia"
  maxiter = 5000
  
  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.0, 0.0)
    hint = "The Julia coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "A very high value is needed to capture detail."
  endparam
}

MyEqn-bare {
  ; Original formula, MyEqnPlusCStlksJ, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 22 May 1999
init:
  complex c = @JuliaCoords
  z = #pixel
  
loop:
  complex z2 = z * z
  z = c * (1 - z2) / (1 + z2) + c

bailout:
  |z| < @bailout

default:
  title = "My Eqn"
  maxiter = 500

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.85625,0.2875)
    hint = "The Julia set coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
}

Newt2_Julia-bare {
  ; Original formula, Flex_Newt2_Julia, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 25 May 1999
init:
  complex c = @JuliaCoords
  complex prev_z = #pixel
  z = #pixel
  
loop:
  prev_z = z
  z = z - (c^2 * z^4 - (c^4 + 1) * z^2 + c^2) / \
          (4 * c^2 * z^3 - 2 * (c^4 + 1) * z)

bailout:
  |z - prev_z| > @error && |z| < @bailout
  
default:
  title = "Newton Julia 2"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-1.1684406885759,-0.8606881002087681)
    hint = "Julia Set Coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
  
  param error
    caption = "Error Value"
    default = 1.0e-5
    hint = "The amount of error allowed."
  endparam
}

NewtMset1-bare {
  ; Original formula, RSNewtMset1, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 29 May 1999
init:
  complex c = #pixel
  complex error = #pixel
  z = sqrt ((1 - c) / 6)
  
loop:
  error = (z^4 + (c-1) * z^2 - c) / (4 * z^3 + 2 * (c-1) * z)
  z = z - error

bailout:
  |error| > @error && |z| < @bailout
  
default:
  title = "Newton Mset"
  maxiter = 3000
  
  param error
    caption = "Error Value"
    default = 1.0e-6
    hint = "The amount of error."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

Pky2J2-bare {
  ; Original formula, Pky2StalksJ2, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 25 May 1999
init:
  complex c = @JuliaCoords
  z = #pixel
  
loop:
  z = 1.0 / (z * z + c)
  z = z * z

bailout:
  |z| < @bailout
  
default:
  title = "Pokorny Squared"
  maxiter = 500

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (1.063125,0.5235417)
    hint = "Julia Set Coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
}

Pky2M2-bare {
  ; Mandel version of, Pky2StalksJ2, by Paul Carlson.
  ; 21 January 2000
init:
  complex c = #pixel
  z = 0
  
loop:
  z = 1.0 / (z * z + c)
  z = z * z

bailout:
  |z| < @bailout
  
default:
  title = "Pokorny Squared Mandel"
  maxiter = 500

  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
  
switch:
  type = "Pky2J2-bare"
  JuliaCoords = #pixel
  bailout = @bailout
}

PkyM2-bare {
  ; Original formula, PkyStalksJ2, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 01 June 1999
init:
  complex c = #pixel
  z = 0
  
loop:
  z = 1.0 / (z * z + c)

bailout:
  |z| < @bailout
  
default:
  title = "Pokorny Mandel"
  maxiter = 500

  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
  
switch:
  type = "PkyJ2-bare"
  JuliaCoords = #pixel
  bailout = @bailout
}

PkyJ2-bare {
  ; Original formula, PkyStalksJ2, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 01 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
  
loop:
  z = 1.0 / (z * z + c)

bailout:
  |z| < @bailout
  
default:
  title = "Pokorny Julia"
  maxiter = 500

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-0.602179463,0.301714302)
    hint = "Julia Set Coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
}

Mod2_Pokorny-bare {
  ; Original formula, Mod2_Pokorny_Rings, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 15 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
  
loop:
  z = 1.0 / (z * z + c) + c + 1.0

bailout:
  |z| < @bailout
  
default:
  title = "Pokorny Julia Mod"
  maxiter = 5000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-2.25,0)
    hint = "Julia Set Coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
}

Mod2_Pokorny_Mandel-bare {
  ; Original formula, Mod2_Pokorny_Rings, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 20 January 2000
init:
  complex c = #pixel
  z = 0
  
loop:
  z = 1.0 / (z * z + c) + c + 1.0

bailout:
  |z| < @bailout
  
default:
  title = "Pokorny Mandel Mod"
  maxiter = 5000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-2.25,0)
    hint = "Julia Set Coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam

switch:
  type = "Mod2_Pokorny-bare"
  JuliaCoords = #pixel
  bailout = @bailout
}

Zf_Ang-bare {
  ; Original formula, Zf_Ang, by Paul Carlson.
  ; Modified to separate fractal formula from coloring algorithm by Ken Childress.
  ; 18 May 1999
init:
  z = #pixel
  complex c = @JuliaCoords
  
loop:
  z = c * (z - 1 / z)

bailout:
  |z| < @bailout

default:
  title = "Z Function Angle"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (-0.058182009,0.675191868)
    hint = "The Julia set coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

Series_Mset-bare {
  ; Original formula, Petals_Series_Mset, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 29 May 1999
init:
  complex c = #pixel
  z = 0
  
loop:
  complex z2 = z * z
  complex z4 = 0.01 * z2 * z2
  complex z8 = z4 * z4
  complex z12 = z4 * z8
  complex z16 = z4 * z12
  z = z2 - z4 - z8 - z12 - z16 + c

bailout:
  |z| < @bailout
  
default:
  title = "Series Mset"
  maxiter = 5000
  
  param bailout
    caption = "Bailout Value"
    default = 1000.0
    hint = "The bailout value."
  endparam

switch:
  type = "Series_Julia-bare"
  JuliaCoords = #pixel
  bailout = bailout
}

Series_Julia-bare {
  ; Original formula, RbAser2J2, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 11 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
  
loop:
  complex z2 = z * z
  complex z4 = 0.01 * z2 * z2
  complex z8 = z4 * z4
  complex z12 = z4 * z8
  complex z16 = z4 * z12
  z = z2 - z4 - z8 - z12 - z16 + c

bailout:
  |z| < @bailout
  
default:
  title = "Series Julia"
  maxiter = 3000
  
  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (3.587297070985906,1.452946845E-7)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e10
    hint = "The bailout value."
  endparam

switch:
  type = "Series_Mset-bare"
  bailout = bailout
}

Halley_M4-bare {
  ; Original formula, FB_Halley_M4, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 02 June 1999
init:
  complex c = #pixel
  z = 0
  
loop:
  complex z2 = z * z
  complex fnc = z2 * z2 - z -c
  complex der = 4 * z * z2 - 1
  complex k = @relax * fnc / (der - 12 * z2 * fnc / (der + der))
  complex z = z - k

bailout:
  |k| > @bailout
  
default:
  title = "Halley M4"
  maxiter = 251

  param Relax
    caption = "Relaxation factor"
    default = 1.0
    hint = "Relaxation factor."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 1.0e-6
    hint = "The bailout value."
  endparam
}

MyEqn_Julia-bare {
  ; Original formula, MyEqn_Func_Julia, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 02 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
  
loop:
  z = c * (1 - z^2) / (1 + z^2)

bailout:
  |z| < @bailout

default:
  title = "My Eqn Julia"
  maxiter = 500

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.85625,0.2875)
    hint = "The Julia set coordinates."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
}

MyEqn_Mandel-bare {
  ; Original formula, MyEqn_Func_Julia, by Paul Carlson.
  ; 21 January 2000
init:
  complex c = #pixel
  z = 0
  
loop:
  z = c * (1 - z^2) / (1 + z^2)

bailout:
  |z| < @bailout

default:
  title = "My Eqn Mandel"
  maxiter = 500

  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "A bailout value of 4 is recommended to work with AtanMethods."
  endparam
  
switch:
  type = "MyEqn_Julia-bare"
  JuliaCoords = #pixel
  bailout = @bailout
}

Newt_Fang_Mset-bare {
  ; Original formula, Newt_Fang_Mset, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 02 June 1999
init:
  a = fn1(#pixel)
  am = a - 1
  z = sqrt(-am / 6)
  prev_mod2 = |z|
  
loop:
  prev_mod2 = |z|
  complex k = z^2
  complex q = z * am
  z = z - (k^2 + k * am - a) / (4 * z * k + q + q)

bailout:
  abs(|z| - prev_mod2) > 0.000001 && |z| < @bailout

default:
  title = "Newton Function Angle Mset"
  maxiter = 251
  
  param bailout
    caption = "Bailout Value"
    default = 1.0e7
    hint = "The bailout value."
  endparam
}

Phoenix_Mandel-bare {
  ; Original formula, PhxAtanJ2, by Paul Carlson.
  ; Modifed for Mandel version.
  ; 12 November 1999
init:
  complex prev_z = 0
  complex v = 0
  complex c = #pixel
  
loop:
  z = prev_z^2 - 0.5 * prev_z + c
  complex b = z^2 - 0.5 * v + c
  v = z
  z = b
  prev_z = z
  
bailout:
  |z| < @bailout
  
default:
  title = "Phoenix Mandel"
  maxiter = 1000

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "Bailout Value."
  endparam
  
switch:
  type = "Phoenix_Julia-bare"
  JuliaCoords = #pixel
  bailout = bailout
}

Phoenix_Julia-bare {
  ; Original formula, PhxAtanJ2, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 03 June 1999
init:
  complex prev_z = #pixel
  complex v = #pixel
  complex c = @JuliaCoords
  
loop:
  z = prev_z^2 - 0.5 * prev_z + c
  complex b = z^2 - 0.5 * v + c
  v = z
  z = b
  prev_z = z
  
bailout:
  |z| < @bailout
  
default:
  title = "Phoenix Julia"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (0.5667, 0.0)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e100
    hint = "Bailout Value."
  endparam
}

Z^ZNewton-bare {
  ; Original formula, IZNewtJ2, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 04 June 1999
init:
  complex c = @JuliaCoords
  z = 1.0 / #pixel
    
loop:
  complex zz = z^z
  z = z - (zz - c) / (zz * (1.0 + log(z)))
  
bailout:
  |z| > @bailout
  
default:
  title = "Z^Z Newton Julia"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (7,0)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e-10
    hint = "The bailout value."
  endparam
}

Spir2_Trunc-bare {
  ; Original formula, Spir2_Trunc, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 04 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
    
loop:
  z = z^2 - c
  z = z - real(z) + abs(real(z))
  
bailout:
  |z| < @bailout
  
default:
  title = "Spiral 2 Truncated"
  maxiter = 5000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-0.378083004695,0.227300793319)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "The bailout value."
  endparam
}

NSpirMset-bare {
  ; Modified for Mset from NSpir-bar, by Paul Carlson.
  ; 14 January 2000
init:
  complex c = #pixel
  z = 0
    
loop:
  z = z^2
  z = z - real(z) + abs(real(z)) - c
  
bailout:
  |z| < @bailout
  
switch:
  type = "NSpir-bare"
  JuliaCoords = #pixel
  bailout = @bailout
  
default:
  title = "N-Spiral Mset"
  maxiter = 5000

  param bailout
    caption = "Bailout Value"
    default = 1.0e10
    hint = "The bailout value."
  endparam
}

NSpir-bare {
  ; Original formula, StarOfDavidNSpir, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 12 July 1999
init:
  complex c = @JuliaCoords
  z = #pixel
    
loop:
  z = z^2
  z = z - real(z) + abs(real(z)) - c
  
bailout:
  |z| < @bailout
  
switch:
  type = "NSpirMset-bare"
  bailout = @bailout
  
default:
  title = "N-Spiral"
  maxiter = 5000

  param JuliaCoords
    caption = "Julia Set Coordinates"
    default = (-0.378083004695,0.227300793319)
    hint = "Julia Set Coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e10
    hint = "The bailout value."
  endparam
}

Newton-bare {
  ; Original formula, Newton_3Way, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 04 June 1999
init:
  float k = @exponent
  z = #pixel
    
loop:
  z = z - @relax * (z^@exponent - 1) / (k * z^(@exponent - 1))
  
bailout:
  |z| < @bailout
  
default:
  title = "Newton"
  maxiter = 255

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam

  param exponent
    caption = "Exponent of Z"
    default = 3.0
    hint = "Exponent of Z."
  endparam
}

Cztoz2-bare {
  ; Original formula, BZtoz2J8, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 04 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
    
loop:
  z = c * z
  z = c * z^z + c
  
bailout:
  |z| < @bailout
  
default:
  title = "Cztoz2"
  maxiter = 300

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.0,0.895)
    hint = "The Julia set coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

IExpJ2-bare {
  ; Original formula, IExpJ2, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 10 June 1999
init:
  complex c = @JuliaCoords
  z = 1.0 / #pixel
    
loop:
  complex k = exp(z)
  z = z - (k - c) / k
  
bailout:
  |z| > @bailout
  
default:
  title = "IExp Julia"
  maxiter = 1000

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (1.0,0.0)
    hint = "The Julia set coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e-10
    hint = "The bailout value."
  endparam
}

IExpM2-bare {
  ; Original formula, IExpJ2, by Paul Carlson.
  ; Modified for Mandel version of the formula by Ken Childress.
  ; 26 January 2000
init:
  complex c = #pixel
  z = 0.0
    
loop:
  complex k = exp(z)
  z = z - (k - c) / k
  
bailout:
  |z| > @bailout
  
default:
  title = "IExp Mandel"
  maxiter = 1000

  param bailout
    caption = "Bailout Value"
    default = 1.0e-10
    hint = "The bailout value."
  endparam
  
switch:
  type = "IExpJ2-bare"
  bailout = @bailout
  JuliaCoords = #pixel
}

CnFrc_Fnc_Mset-bare {
  ; Original formula, CnFrc_Fnc_Mset, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 10 June 1999
init:
  z = 0.0
    
loop:
  complex k = z^2 + #pixel
  z = k - fn1(1.0 / (k + 1.0 / (k + 1.0 / (k + 1.0 / (k + 1.0 / (k + 1.0))))))
  
bailout:
  |z| < @bailout
  
default:
  title = "Cont Frac Func Mset"
  maxiter = 1000

  param bailout
    caption = "Bailout Value"
    default = 1.0e10
    hint = "The bailout value."
  endparam

switch:
  type = "CnFrC_Fnc_Julia-bare"
  bailout = @bailout
  JuliaCoords = #pixel
}

CnFrc_Fnc_Julia-bare {
  ; Original formula, CnFrc_Fnc_Mset, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 10 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
    
loop:
  complex k = z^2 + c
  z = k - fn1(1.0 / (k + 1.0 / (k + 1.0 / (k + 1.0 / (k + 1.0 / (k + 1.0))))))
  
bailout:
  |z| < @bailout
  
default:
  title = "Cont Frac Func Julia"
  maxiter = 1000

  param bailout
    caption = "Bailout Value"
    default = 1.0e10
    hint = "The bailout value."
  endparam
  
  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.0, 0.0)
    hint = "The Julia coordinates."
  endparam
}

Newt2_Mset-bare {
  ; Original formula, Newt2_Stalks_Mset, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 10 June 1999
init:
  complex c = #pixel
  csqd = c * c
  icsqd = 1.0 / csqd
  a = csqd - icsqd
  z = sqrt(a / 6.0)
  
loop:
  z = (3 * z^4 - a * z^2 + 1) / (4 * z^3 - 2 * a * z)

bailout:
  |z| < @bailout
  
default:
  title = "Newton Mset 2"
  maxiter = 2000

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

Newt3_Mset-bare {
  ; Original Fractint formula, Newt3_Atan_Mset, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 20 January 2000
  ;
  ; F(w)   = w^3 + (c - 1) * w - c
  ; F'(w)  = 3 * w^2 + c - 1
  ; F''(w) = 6 * w,  so initialize w to zero
  ;
init:
  complex c = #pixel
  z = 0
  c1 = c - 1
  
loop:
  z = z - (z * (z^2 + c1) - c) / (3 * z^2 + c1)

bailout:
  |z| < @bailout
  
default:
  title = "Newton Mset 3"
  maxiter = 2000

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

FnLambMset-bare {
  ; Original formula, RbFnLambM2, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 11 June 1999
init:
  complex c = #pixel
  z = @initValue
  
loop:
  z = c * z * (1 - z)
  z = z - fn1(z)

bailout:
  |z| < @bailout
  
default:
  title = "Function Lambda Mset"
  maxiter = 5000
  
  param initValue
    caption = "Initial Value"
    default = (0.5, 0.0)
    hint = "Initial value."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e10
    hint = "The bailout value."
  endparam
}

Celtic_Julia-bare {
  ; Original formula, Celtic_Julia, by Paul Carlson.
  ; Modified to separate coloring formula by Ken Childress.
  ; 11 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
  
loop:
  z = z^2
  z = z - real(z) + abs(real(z)) - c

bailout:
  |z| < @bailout
  
default:
  title = "Celtic Julia"
  maxiter = 255

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.690498547,0.192997741)
    hint = "The Julia set coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "The bailout value."
  endparam
}

Celtic_Mandel-bare {
  ; Original formula, Celtic_Julia, by Paul Carlson.
  ; Modified for Mandel version of the formula by Ken Childress.
  ; 27 January 2000
init:
  complex c = #pixel
  z = 0
  
loop:
  z = z^2
  z = z - real(z) + abs(real(z)) - c

bailout:
  |z| < @bailout
  
default:
  title = "Celtic Mandel"
  maxiter = 255

  param bailout
    caption = "Bailout Value"
    default = 4.0
    hint = "The bailout value."
  endparam
 
switch:
  type = "Celtic_Julia-bare"
  bailout = @bailout
  JuliaCoords = #pixel
}

CZCubedJulia-bare {
  ; Original formula, Qd_Julia, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 15 June 1999
init:
  complex c = @JuliaCoords
  z = #pixel
    
loop:
  z = c * (z^2 + z) - c
  
bailout:
  |z| < @bailout
  
default:
  title = "CZCubed Julia"
  maxiter = 5000

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (-0.38769624,-0.27939799)
    hint = "The Julia set coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

CZCubedMandel-bare {
  ; Original formula, Qd_Julia, by Paul Carlson.
  ; Modified for Mandel version by Ken Childress.
  ; 15 June 1999
init:
  complex c = #pixel
  z = 0
    
loop:
  z = c * (z^2 + z) - c
  
bailout:
  |z| < @bailout
  
default:
  title = "CZCubed Mandel"
  maxiter = 5000

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
  
switch:
  type = "CZCubedJulia-bare"
  bailout = @bailout
  JuliaCoords = #pixel
}

Newt3-bare {
  ; Original formula, Newt3_Atan, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 26 June 1999
init:
  z = #pixel

loop:
  err = (z^3 - 1.0) / (3.0 * z^2)
  z = z - err

bailout:
  |err| > @epsilon

default:
  title = "Newton 3"
  maxiter = 1000
    
  param epsilon
    caption = "Error Value"
    default = 1.0e-6
    hint = "The error value."
  endparam
}

Secant3-bare {
  ; Original formula, Secant3_Atan, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 19 July 1999
init:
  ;The initial two points
  complex x0 = @m0 * #pixel
  complex x1 = @m1 * #pixel

  ;The value of the function at the two points
  complex f0 = x0^3 - 1
  complex f1 = x1^3 - 1

loop:
  ;Compute a new second point
  z = x1 - @relax * f1 * (x1 - x0) / (f1 - f0)

  ;Update the points and functions
  x0 = x1
  x1 = z
  f0 = f1
  f1 = z^3 - 1.0

bailout:
  |z| > @bailout

default:
  title = "Secant 3"
  maxiter = 1000
    
  param m0
    caption = "x0 multiplier"
    default = 0.1
    hint = "x0 multiplier."
  endparam

  param m1
    caption = "x1 multiplier"
    default = -0.1
    hint = "x1 multiplier."
  endparam
  
  param relax
    caption = "Relaxation factor"
    default = 1.0
    hint = "Relaxation factor."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e-20
    hint = "The bailout value."
  endparam
}

Muller3-bare {
  ; Original formula, Muller3_Atan, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 19 July 1999
init:
  ;The initial three points on the parabola
  complex x0 = @m0 * #pixel
  complex x1 = @m1 * #pixel
  complex x2 = @m2 * #pixel

  ;The value of the function at the three points
  complex f0 = x0^3 - 1
  complex f1 = x1^3 - 1
  complex f2 = x2^3 - 1

  ;The parabolic variables
  complex h1 = x1 - x0
  complex h2 = x2 - x1
  complex delta1 = (f1 - f0) / h1
  complex delta2 = (f2 - f1) / h2
  complex d = (delta2 - delta1) / (h2 - h1)

loop:
  ;Compute a new third point on the parabola
  f2 = x2^3 - 1
  complex b = delta2 + h2 * d
  complex v = sqrt(b * b - 4.0 * f2 * d)
  IF (|b - v| < |b + v|)
    complex w = b + v
  ELSE
    w = b - v
  ENDIF
  complex h = -2.0 * f2 / w
  complex z = x2 + h

  ;Relocate the parabola
  x0 = x1
  x1 = x2
  x2 = z

  ;Recompute the value of the function at the three points
  f0 = x0^3 - 1
  f1 = x1^3 - 1
  f2 = x2^3 - 1

  ;Recompute the parabolic variables
  h1 = x1 - x0
  h2 = x2 - x1
  delta1 = (f1 - f0) / h1
  delta2 = (f2 - f1) / h2
  d = (delta2 - delta1) / (h2 - h1)

bailout:
  |z| > @bailout

default:
  title = "Muller 3"
  maxiter = 1000
    
  param m0
    caption = "x0 multiplier"
    default = 0.1
    hint = "x0 multiplier."
  endparam

  param m1
    caption = "x1 multiplier"
    default = -0.1
    hint = "x1 multiplier."
  endparam
  
  param m2
    caption = "x2 multiplier"
    default = 0.0
    hint = "x2 multiplier."
  endparam
    
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

Newt4-bare {
  ; Original formula, Newt4AtanM2, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 19 July 1999
init:
  complex c = #pixel
  z = sqrt((1.0 - c) / 6.0)

loop:
  err = (z^4 + (c - 1.0) * z^2 - c) / (4.0 * z^3 + 2.0 * (c - 1.0) * z)
  z = z - err

bailout:
  |err| > @epsilon

switch:
  type = "Newt4J2-bare"
  JuliaCoords = #pixel

default:
  title = "Newton 4"
  maxiter = 1000
  periodicity = 0
    
  param epsilon
    caption = "Error Value"
    default = 1.0e-6
    hint = "The error value."
  endparam
}

Newt4J2-bare {
  ; Original formula, Newt4AtanJ2, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 22 July 1999
init:
  complex c = @JuliaCoords
  z = #pixel

loop:
  err = (z^4 + (c - 1.0) * z^2 - c) / (4.0 * z^3 + 2.0 * (c - 1.0) * z)
  z = z - err

bailout:
  |err| > @epsilon

switch:
  type = "Newt4-bare"

default:
  title = "Newton 4 Julia"
  maxiter = 1000
  periodicity = 0
    
  param epsilon
    caption = "Error Value"
    default = 1.0e-6
    hint = "The error value."
  endparam

  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.0,0.0)
    hint = "The Julia set coordinates."
  endparam
}

Steff-bare {
  ; Original formula, Steff3_Atan, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 20 July 1999
init:
  complex pt0 = #pixel

loop:
  ;Compute the next approximation
  complex pt1 = 1.0 / sqr(pt0)
  complex pt2 = 1.0 / sqr(pt1)
  z = pt0 - (pt1 - pt0) * (pt1 - pt0) / (pt2 - pt1 - pt1 + pt0)
  pt0 = z

bailout:
  |z| > @bailout

default:
  title = "Steff 3"
  maxiter = 1000
    
  param bailout
    caption = "Bailout Value"
    default = 1.0e-100
    hint = "The bailout value."
  endparam
}

PWC_Eqn_Mset-bare {
  ; Original formula, PWC_Eqn_Mset, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 24 July 1999
init:
  complex c = #pixel
  z = 0

loop:
  z = (z^2 + c) * (1 - z^2) / (1 + z^2)

bailout:
  |z| < @bailout
  
switch:
  type = "PWC_Eqn_Julia-bare"
  JuliaCoords = #pixel
  bailout = bailout  

default:
  title = "PWC Eqn Mset"
  maxiter = 1000
    
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

PWC_Eqn_Julia-bare {
  ; Original formula, PWC_Eqn_Mset, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 24 July 1999
init:
  complex c = @JuliaCoords
  z = #pixel

loop:
  z = (z^2 + c) * (1 - z^2) / (1 + z^2)

bailout:
  |z| < @bailout

default:
  title = "PWC Eqn Julia"
  maxiter = 1000
    
  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.85625,0.2875)
    hint = "The Julia set coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

PWC2_Eqn_Mset-bare {
  ; Original formula, PWC_Eqn_Mset, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 24 July 1999
init:
  complex c = #pixel
  z = 0

loop:
  z = (z^2 + c) * (1 - z^2) / (1 + z^2) + c

bailout:
  |z| < @bailout
  
switch:
  type = "PWC2_Eqn_Julia-bare"
  JuliaCoords = #pixel
  bailout = bailout  

default:
  title = "PWC2 Eqn Mset"
  maxiter = 1000
    
  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

PWC2_Eqn_Julia-bare {
  ; Original formula, PWC2_Eqn_Mset, by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 24 July 1999
init:
  complex c = @JuliaCoords
  z = #pixel

loop:
  z = (z^2 + c) * (1 - z^2) / (1 + z^2) + c

bailout:
  |z| < @bailout

default:
  title = "PWC2 Eqn Julia"
  maxiter = 1000
    
  param JuliaCoords
    caption = "Julia Coordinates"
    default = (0.85625,0.2875)
    hint = "The Julia set coordinates."
  endparam

  param bailout
    caption = "Bailout Value"
    default = 1.0e20
    hint = "The bailout value."
  endparam
}

Popcorn-bare {
  ; Original formula, FB_Popcorn (Fractint), by Paul Carlson.
  ; Modified to remove coloring parts of the formula by Ken Childress.
  ; 18 November 1999
init:
  z = 0
  float x = real(#pixel)
  float y = imag(#pixel)

loop:
  float prev_x = x
  x = x - @Popcorn * sin(y + tan(3 * y))
  y = y - @Popcorn * sin(prev_x + tan(3 * prev_x))
  z = x + flip(y)

bailout:
  |z| < @bailout

default:
  title = "Popcorn"
  maxiter = 250
    
  param Popcorn
    caption = "Popcorn Parameter"
    default = 0.0
    hint = "The popcorn parameter."
  endparam
  
  param bailout
    caption = "Bailout Value"
    default = 64.0
    hint = "The bailout value."
  endparam
}