common
Class Location

Object
  common:Generic
      common:Transform
          common:UserTransform
              common:Location

class 
UserTransform:Location

This transform works like the Location tab. It is useful if you want to reposition something without the extra trap-specific options of Trap Position.

Ultra Fractal Source

Toggle UF Source Code Display

 class Location(UserTransform) {
   ; This transform works like the Location tab. It is useful if you want
   ; to reposition something without the extra trap-specific options of
   ; Trap Position.
   
 public:
   func Location(Generic pparent)
     UserTransform.UserTransform(pparent)
   endfunc
   
   func Init(complex pz)
     UserTransform.Init(pz)
   endfunc
   
   complex func Iterate(complex pz)
     UserTransform.Iterate(pz)
 
     pz = (real(pz) + imag(pz) * tan(-@p_skew*#pi/180.0))/@p_stretch + flip(imag(pz))
     complex r =     ( cos(@p_angle*#pi/180.0)*real(pz) - sin(@p_angle*#pi/180.0)*imag(pz) ) + \
           flip( cos(@p_angle*#pi/180.0)*imag(pz) + sin(@p_angle*#pi/180.0)*real(pz) )
     pz = @p_center + r/@p_magn
     return pz
   endfunc
   
 default:
   title = "Location"
   
   int param v_location
     caption = "Version (Location)"
     default = 100
     hint = "This version parameter is used to detect when a change has been made to the formula that is incompatible with the previous version. When that happens, this field will reflect the old version number to alert you to the fact that an alternate rendering is being used."
     visible = @v_location < 100
   endparam
   
   complex param p_center
     caption = "Center"
     default = (0,0)
     hint = "Sets the center of the image."
   endparam
   float param p_magn
     caption = "Magnification"
     default = 1.0
     hint = "Sets the magnification."
   endparam
   float param p_angle
     caption = "Rotation Angle"
     default = 0.0
     hint = "Sets the rotation angle."
   endparam
   float param p_stretch
     caption = "Stretch (X/Y)"
     default = 1.0
     hint = "Sets the X/Y stretching."
   endparam
   float param p_skew
     caption = "Skew Angle"
     default = 0.0
     hint = "Sets the skew angle."
   endparam
 }
 

Constructor Summary

Location()

Location(Generic pparent)

Method Summary

void	Init(complex pz) Set up for a sequence of values
complex	Iterate(complex pz) Transform a single point within a sequence

Methods inherited from class common:Transform

IsSolid, IterateSilent

Methods inherited from class common:Generic

GetParent

Methods inherited from class Object

Constructor Detail

Location

public Location(Generic pparent)

Location

public Location()

Method Detail

Init

public void Init(complex pz)

Description copied from class: Transform

Set up for a sequence of values

This function will be called at the beginning of each sequence of values (e.g. at the beginning of each fractal orbit). It will be called even if only one value is being transformed (e.g. a normal transformation formula). Use this to perform any setup that is exactly the same for each value in the sequence being transformed.

Overrides:

Init in class Transform

Parameters:

pz - the value representing the sequence; for a normal transformation formula use, this will be #pixel. In some cases this may differ from the first value passed to Iterate() if the calling code applies some other transformations.

Iterate

public complex Iterate(complex pz)

Description copied from class: Transform

Transform a single point within a sequence

After a sequence has been set up with Init(), this function will be called once for each value in the sequence. Note that all values in the sequence must be processed in order (they cannot be processed out of order). If the sequence contains only one value, Init() will still be called and then Iterate() will be called just once.

Overrides:

Iterate in class Transform

Parameters:

pz - the complex value to be transformed

Returns:

the transformed value