REB_3RDIMMagnet2

 class REB_3RDIMMagnet2(common.ulb:ConvergentDivergentFormula) {
 ;
 public:
   ; constructor
   func REB_3RDIMMagnet2(Generic pparent)
      ConvergentDivergentFormula.ConvergentDivergentFormula(pparent)
    endfunc
 
   ; initialize the formula
   complex func Init(complex pz)
     ConvergentDivergentFormula.Init(pz)
     complex z2 = pz
     pz = @p1*real(@start)+flip(imag(@start))
     m_c = @p2+real(z2)+flip(imag(z2)*@p1)
     return pz
   endfunc
 
   ; call for each iterated point
   complex func Iterate(complex pz)
     ConvergentDivergentFormula.Iterate(pz)
     return sqr( (pz^3 + 3*(m_c-1)*pz + (m_c-1)*(m_c-2)) / \
                 (3*pz^2 + 3*(m_c-2)*pz + (m_c-1)*(m_c-2) + 1) )
   endfunc
 
   ; Override the default function for bailout
   bool func IsBailedOut(complex pz)
     return |pz| >= @p_upperbailout || |pz - 1| <= @p_lowerbailout
   endfunc
 
 private:
   complex m_c
 
 default:
   title = "3RDIM Magnet 2"
   int param v_3RDIMMagnet2
     caption = "Version (3RDIM Magnet 2)"
     default = 100
     hint = "This version parameter is used to detect when a change has been made to the formula that is incompatible with the previous version. When that happens, this field will reflect the old version number to alert you to the fact that an alternate rendering is being used."
     visible = @v_3RDIMMagnet2< 100
   endparam
   heading
     text = "Most Mandelbrot-type formulas initialize in the z plane and iterate \
            in the c plane. Gordon Lamb proposed a geometry which involves iteration \
            in the zc plane (type SJ) or in the cz plane (type 3RDIM). A 'Plane \
            hybridization' value of zero gives pure zc or cz iteration, while a \
            'Plane hybridization' value of one gives the classical c plane iteration. \
            Intermediate values can produce very interesting results."
   endheading
   param start
     caption = "Perturbation"
     default = (0, 0)
     hint = "Starting value for each point. You can use this to \
             'perturb' the fractal. Use (0, 0) for the classic set."
   endparam
   float param p1
      caption = "Plane hybridization"
      default = 0.5
      min = 0
      max = 1
   endparam
   param p2
     caption = "Iteration Plane position"
     default = (0.0,0.0)
   endparam
   param p_upperbailout ; Overrides p_upperbailout from ConvergentDivergentFormula
     caption = "Bailout value"
     default = 100.0
     min = 1
 ;    exponential = true
     hint = "This parameter defines how soon an orbit bails out while \
             iterating. Larger values give smoother outlines; smaller values \
             generally produce more interesting shapes around the set."
   endparam
   param p_lowerbailout ; Overrides p_lowerbailout from ConvergentDivergentFormula
     caption = "Convergent bailout value"
     default = 0.00001
     min = 0
 ;    exponential = true
     hint = "This parameter defines how soon a convergent orbit bails out while \
             iterating. Smaller values give more precise results but usually \
             require more iterations."
   endparam
   complex param p_power ; Hide p_power from Formula
     visible = false
   endparam
 }

Method Summary
`complex`	`Init(complex pz)` initialize the formula
`boolean`	`IsBailedOut(complex pz)` Override the default function for bailout
`complex`	`Iterate(complex pz)` call for each iterated point

Constructor Summary
`REB_3RDIMMagnet2()`
`REB_3RDIMMagnet2(Generic pparent)` constructor

reb Class REB_3RDIMMagnet2

REB_3RDIMMagnet2

REB_3RDIMMagnet2

Init

Iterate

IsBailedOut

reb
Class REB_3RDIMMagnet2