REB_3RDIMSpiderJulia

 class REB_3RDIMSpiderJulia(common.ulb:DivergentFormula) {
 public:
   import "common.ulb"
 
   ; constructor
   func REB_3RDIMSpiderJulia(Generic pparent)
      DivergentFormula.DivergentFormula(pparent)
    endfunc
 
   ; initialize the formula
   complex func Init(complex pz)
     DivergentFormula.Init(pz)
     complex z2 = pz
     pz=@p1*real(z2)+flip(imag(z2))
     m_c=@p2+real(@p3)+flip(imag(@p3)*@p1)
     return pz
   endfunc
 
   ; call for each iterated point
   complex func Iterate(complex pz)
     DivergentFormula.Iterate(pz)
     pz=pz^2+m_c
     m_c=m_c/2+pz
     return pz
   endfunc
 
   ; Override the default function for bailout
   bool func IsBailedOut(complex pz)
     bool bail = false
     if @test == 0
       bail = (|pz| > @p_bailout)
     elseif @test == 1
       bail = (sqr(real(pz)) > @p_bailout)
     elseif @test == 2
       bail = (sqr(imag(pz)) > @p_bailout)
     elseif @test == 3
       bail = (sqr(real(pz)) > @p_bailout || sqr(imag(pz)) > @p_bailout)  
     elseif @test == 4
       bail = (sqr(real(pz)) > @p_bailout && sqr(imag(pz)) > @p_bailout)  
     elseif @test == 5
       bail = (sqr(abs(real(pz)) + abs(imag(pz))) > @p_bailout)
     elseif @test == 6
       bail = (sqr(real(pz) + imag(pz)) > @p_bailout)
     endif
     return bail
   endfunc
   
 protected:
   complex m_c  
 
 default:
   title = "3RDIM Spider Julia"
   int param v_3RDIMSpiderJulia
     caption = "Version (3RDIM Spider Julia)"
     default = 100
     hint = "This version parameter is used to detect when a change has been made to the formula that is incompatible with the previous version. When that happens, this field will reflect the old version number to alert you to the fact that an alternate rendering is being used."
     visible = @v_3RDIMSpiderJulia < 100
   endparam
   heading
     text = "Most Mandelbrot-type formulas initialize in the z plane and iterate \
            in the c plane. Gordon Lamb proposed a geometry which involves iteration \
            in the zc plane (type SJ) or in the cz plane (type 3RDIM). A 'Plane \
            hybridization' value of zero gives pure zc or cz iteration, while a \
            'Plane hybridization' value of one gives the classical c plane iteration. \
            Intermediate values can produce very interesting results."
   endheading
   float param p1
      caption = "Plane hybridization"
      default = 0.5
      min = 0
      max = 1
   endparam
   param p2
     caption = "Iteration Plane position"
     default = (0.0,0.0)
   endparam
   param test
     caption = "Bailout Test"
     default = 0
     enum = "mod" "real" "imag" "or" "and" "manh" "manr"
     hint = "mod is the standard bailout. The remaining bailout methods are \
             from Fractint."
   endparam
   float param p_bailout ; Overrides p_bailout from DivergentFormula
     caption = "Bailout value"
     default = 10000.0
     min = 1.0
     hint = "Use a value of 4 if the bailout test is other than mod."
   endparam
   param p3
     caption = "Julia seed"
     default = (0.1,-0.625)
   endparam
   complex param p_power ; Overrides p_power from Formula
     caption = "Power"
     default = (2,0)
     visible = false
   endparam
 }

Method Summary
`complex`	`Init(complex pz)` initialize the formula
`boolean`	`IsBailedOut(complex pz)` Override the default function for bailout
`complex`	`Iterate(complex pz)` call for each iterated point

Constructor Summary
`REB_3RDIMSpiderJulia()`
`REB_3RDIMSpiderJulia(Generic pparent)` constructor

reb Class REB_3RDIMSpiderJulia

REB_3RDIMSpiderJulia

REB_3RDIMSpiderJulia

Init

Iterate

IsBailedOut

reb
Class REB_3RDIMSpiderJulia