reb
Class REB_FrameRobert_Switch

Object
  common:Generic
      common:Formula
          reb:Switch
              reb:REB_FrameRobert_Switch

class 
Switch:REB_FrameRobert_Switch

Ultra Fractal Source

Toggle UF Source Code Display

 class REB_FrameRobert_Switch(Switch) {
 public:
   import "common.ulb"
 
   ; constructor
   func REB_FrameRobert_Switch(Generic pparent)
      Switch.Switch(pparent)
      m_power = @p_power
      m_mand = @p_mand
      m_jul = @p_jul
      m_bailout = @p_upperbailout
      m_bailout2 = @p_lowerbailout
      m_c = @m_c
      m_test = @test
    endfunc
 
   ; initialize the formula
   complex func Init(complex pz)
     Switch.Init(pz)
     if m_mand
       m_c = pz
     endif
     return pz
   endfunc
 
   ; call for each iterated point
   complex func Iterate(complex pz)
     Switch.Iterate(pz)
     return pz^3/5 + pz^2 + m_c
   endfunc
 
   ; Override the default function for bailout
   bool func IsBailedOut(complex pz)
     bool bail = false
     if m_test == 0
       bail = (|pz| > m_bailout)
     elseif m_test == 1
       bail = (sqr(real(pz)) > m_bailout)
     elseif m_test == 2
       bail = (sqr(imag(pz)) > m_bailout)
     elseif m_test == 3
       bail = (sqr(real(pz)) > m_bailout || sqr(imag(pz)) > m_bailout)  
     elseif m_test == 4
       bail = (sqr(real(pz)) > m_bailout && sqr(imag(pz)) > m_bailout)  
     elseif m_test == 5
       bail = (sqr(abs(real(pz)) + abs(imag(pz))) > m_bailout)
     elseif m_test == 6
       bail = (sqr(real(pz) + imag(pz)) > m_bailout)
     endif
     return bail
   endfunc
   
 default:
   title = "FrameRobert Switch"
   int param v_framerobertswitch
     caption = "Version (FrameRobert Switch)"
     default = 100
     hint = "This version parameter is used to detect when a change has been made to the formula that is incompatible with the previous version. When that happens, this field will reflect the old version number to alert you to the fact that an alternate rendering is being used."
     visible = @v_framerobertswitch < 100
   endparam
   complex param m_c
     caption = "Julia Seed"
     default = (0,0)
     visible = false
   endparam
   bool param p_mand
     caption = "Mandel Type"
     default = true
     visible = false
   endparam
   bool param p_jul
     caption = "Julia Type"
     default = false
     visible = false
   endparam
   param test
     caption = "Bailout Test"
     default = 0
     enum = "mod" "real" "imag" "or" "and" "manh" "manr"
     hint = "mod is the standard bailout. The remaining bailout methods are \
             from Fractint."
   endparam
   float param p_upperbailout
     caption = "Bailout value (Divergent)"
     default = 1e10
     min = 1.0
   endparam
   float param p_lowerbailout
     caption = "Bailout value"
     default = 1e-10
     visible = false
   endparam
   complex param p_power ; Overrides p_power from Formula
     caption = "Power"
     default = (2,0)
     visible = false
   endparam
 }
 

Constructor Summary

REB_FrameRobert_Switch()

REB_FrameRobert_Switch(Generic pparent)
constructor

Method Summary

complex	Init(complex pz) initialize the formula
boolean	IsBailedOut(complex pz) Override the default function for bailout
complex	Iterate(complex pz) call for each iterated point

Methods inherited from class reb:Switch

GetParams, SetParams

Methods inherited from class common:Formula

GetLowerBailout, GetPrimaryExponent, GetUpperBailout

Methods inherited from class common:Generic

GetParent

Methods inherited from class Object

Constructor Detail

REB_FrameRobert_Switch

public REB_FrameRobert_Switch(Generic pparent)

constructor

REB_FrameRobert_Switch

public REB_FrameRobert_Switch()

Method Detail

Init

public complex Init(complex pz)

initialize the formula

Overrides:

Init in class Switch

Parameters:

pz - seed value for the sequence; for a normal fractal formula, this will be #pixel

Returns:

first value in the sequence; this corresponds to #z in a fractal formula

Iterate

public complex Iterate(complex pz)

call for each iterated point

Overrides:

Iterate in class Switch

Parameters:

pz - previous value in the sequence; corresponds to #z in a fractal formula. Note that you should always use this value for computing the next iteration, rather than a saved value, as the calling code may modify the returned value before passing it back to the next Iterate() call.

Returns:

the next value in the sequence

IsBailedOut

public boolean IsBailedOut(complex pz)

Override the default function for bailout

Overrides:

IsBailedOut in class Switch

Parameters:

pz - last sequence value to test; this should be the value returned from the previous Iterate() call. Note that it is acceptable to ignore pz and use m_BailedOut, but any code calling IsBailedOut() should pass in the correct pz for Formula classes which do not use m_BailedOut.

Returns:

true if the sequence has bailed out (i.e. should be terminated)