reb
Class REB_TrapShapeCassiniOvals

Object
  common:Generic
      common:TrapShape
          reb:REB_TrapShapeCassiniOvals

class 
TrapShape:REB_TrapShapeCassiniOvals

This shape uses the Cassini ovals function.

This variant of the function involves taking a square root so there are two solutions. A signed and absolute value version of the distance is also available. The transformed value is the complex return value of the function.

Ultra Fractal Source

Toggle UF Source Code Display

 class REB_TrapShapeCassiniOvals(common.ulb:TrapShape) {
  ; This shape uses the Cassini ovals function.<br>
  ; <p>
  ; This variant of the function involves taking a square root
  ; so there are two solutions. A signed and absolute value version of
  ; the distance is also available. The transformed value is the
  ; complex return value of the function.
  public:
    import "common.ulb"
 
 ; Constructor
    func REB_TrapShapeCassiniOvals(Generic pparent)
      TrapShape.TrapShape(pparent)
    endfunc
    
   ; Call this for each iteration being trapped.
    float func Iterate(complex pz)
     TrapShape.Iterate(pz)
      float theta = 0
      float d =  0
      float rr = 0
      theta = atan2(pz)
     int sgn = 1
     if @sgn
       sgn = -1
     endif
      if @negroot
        rr = 0.5*@a*(cos(2*theta)-((@b*0.1/(@a*0.5))^4-sin(2*theta)^2)^0.5)^0.5
      else
        rr = 0.5*@a*(cos(2*theta)+((@b*0.1/(@a*0.5))^4-sin(2*theta)^2)^0.5)^0.5
      endif
      if @absval
        d = abs(cabs(pz) - cabs(rr*cos(theta)+ sgn*flip(rr*sin(theta))))
      else
        d = cabs(pz - (rr*cos(theta) + sgn*flip(rr*sin(theta))))
      endif
      m_LastZ = (rr*cos(theta) + sgn*flip(rr*sin(theta)))
      return d
    endfunc
    
  default:
    title = "Cassini Ovals"
   int param v_trapshapecassiniovals
     caption = "Version (Trap Shape Cassini Ovals)"
     default = 101
     hint = "This version parameter is used to detect when a change has been made to the formula that is incompatible with the previous version. When that happens, this field will reflect the old version number to alert you to the fact that an alternate rendering is being used."
     visible = @v_trapshapecassiniovals < 101
   endparam
    
    float param a
      caption = "Polar parameter"
      default = 0.2
      hint = "Affects spread and scale of trap"
    endparam
 
    float param b
      caption = "2nd Polar parameter"
      default = 1.0
      hint = "Affects spread and scale of trap"
    endparam
    bool param sgn
      caption = "Conjugate transform"
      default = false
    endparam
    param absval
      caption = "Absolute Value"
      default = false
    endparam
    param negroot
      caption = "Quad Neg Root"
      default = false
    endparam
  }
 

Constructor Summary

REB_TrapShapeCassiniOvals()

REB_TrapShapeCassiniOvals(Generic pparent)
Constructor

Method Summary

float

Iterate(complex pz) Call this for each iteration being trapped.

Methods inherited from class common:TrapShape

GetColorChannel, GetTextureValue, GetTransformedPoint, Init, IterateSilent, SetThreshold

Methods inherited from class common:Generic

GetParent

Methods inherited from class Object

Constructor Detail

REB_TrapShapeCassiniOvals

public REB_TrapShapeCassiniOvals(Generic pparent)

Constructor

REB_TrapShapeCassiniOvals

public REB_TrapShapeCassiniOvals()

Method Detail

Iterate

public float Iterate(complex pz)

Call this for each iteration being trapped.

Overrides:

Iterate in class TrapShape