reb
Class REB_TrapShapeChip2

Object
  common:Generic
      common:TrapShape
          reb:REB_TrapShapeChip2

class 
TrapShape:REB_TrapShapeChip2

Based upon the Chip strange attractor. Can also be used as a texture.

Ultra Fractal Source

Toggle UF Source Code Display

 class REB_TrapShapeChip2(common.ulb:TrapShape) {
 ; Based upon the Chip strange attractor. Can also be used as a texture. <br>
  public:
    import "common.ulb"
 
 ; Constructor
    func REB_TrapShapeChip2(Generic pparent)
      TrapShape.TrapShape(pparent)
    endfunc
 
   ; Call this for each iteration being trapped.      
    float func Iterate(complex pz)
     TrapShape.Iterate(pz)
      float scale = sqrt(@h1*@h1+@h2*@h2+@h3*@h3)
      scale = @scaleadj*scale
      int sgn = 1
      if @sgn
        sgn = -1
      endif
      complex p = pz
      p = @fn1(p)
      float x = real(p)*scale
      float y = imag(p)*scale
      float pxx = 0
      int att_iter = 0
 
      while att_iter < @max_att_iterations
        pxx = x
        if x != 0
          x = y - x/abs(x)*cos(sqr(log(abs(@h2*x-@h3))))*atan(sqr(log(abs(@h3*x-@h2))))
        else
          x = y - cos(sqr(log(abs(@h2*x-@h3))))*atan(sqr(log(abs(@h3*x-@h2))))
        endif
        y = @h1 - pxx
        att_iter = att_iter + 1
      endwhile
      m_LastZ = @fn2(x + sgn*flip(y))
      float d = abs(|pz| - |m_LastZ|)
      return d
    endfunc
    
  default:
    title = "Chip 2"
   int param v_trapshapechip2
     caption = "Version (Trap Shape Chip 2)"
     default = 101
     hint = "This version parameter is used to detect when a change has been made to the formula that is incompatible with the previous version. When that happens, this field will reflect the old version number to alert you to the fact that an alternate rendering is being used."
     visible = @v_trapshapechip2 < 101
   endparam
    
    float param h1
      caption = "Chip param 1"
      default = -15
    endparam
    float param h2
      caption = "Chip param 2"
      default = -3
    endparam
    float param h3
      caption = "Chip param 3"
      default = 1
    endparam
    float param scaleadj
      caption = "Scale"
      default = 1
    endparam
    int param max_att_iterations
      caption = "Attractor iterations"
      default = 1
    endparam
   func fn1
     caption = "Pre Function"
     default = atan()
   endfunc
   func fn2
     caption = "Post Function"
     default = sinh()
   endfunc
    bool param sgn
      caption = "Conjugate transform"
      default = false
    endparam
  }
 

Constructor Summary

REB_TrapShapeChip2()

REB_TrapShapeChip2(Generic pparent)
Constructor

Method Summary

float

Iterate(complex pz) Call this for each iteration being trapped.

Methods inherited from class common:TrapShape

GetColorChannel, GetTextureValue, GetTransformedPoint, Init, IterateSilent, SetThreshold

Methods inherited from class common:Generic

GetParent

Methods inherited from class Object

Constructor Detail

REB_TrapShapeChip2

public REB_TrapShapeChip2(Generic pparent)

Constructor

REB_TrapShapeChip2

public REB_TrapShapeChip2()

Method Detail

Iterate

public float Iterate(complex pz)

Call this for each iteration being trapped.

Overrides:

Iterate in class TrapShape