reb
Class REB_TrapShapeFoliumOfDescartes

Object
  extended by common:Generic
      extended by common:TrapShape
          extended by reb:REB_TrapShapeFoliumOfDescartes

class 
TrapShape:REB_TrapShapeFoliumOfDescartes

This shape uses the folium of Descartes function.

This variant of the function has a signed and absolute value version of the distance. The function also has a complex conjugate and a polar variant. The transformed value is the complex return value of the function.


Ultra Fractal Source

Toggle UF Source Code Display

 class REB_TrapShapeFoliumOfDescartes(common.ulb:TrapShape) {
  ; This shape uses the folium of Descartes function.<br>
  ; <p>
  ; This variant of the function has a signed and absolute value
  ; version of the distance. The function also has a complex conjugate and a
  ; polar variant. The transformed value is the complex return value of the function.
  public:
    import "common.ulb"
 
 ; Constructor
    func REB_TrapShapeFoliumOfDescartes(Generic pparent)
      TrapShape.TrapShape(pparent)
    endfunc
    
   ; Call this for each iteration being trapped.
    float func Iterate(complex pz)
     TrapShape.Iterate(pz)
      float theta = 0
      float d =  0
      float rr = 0
      theta = atan2(pz)
     int sgn = 1
     if @sgn
       sgn = -1
     endif
      rr = 0.3*@a*tan(theta)/(cos(theta)*(1+tan(theta)^3))
      if !@ptraps
        if @absval
          d = abs(cabs(pz) - cabs(rr*cos(theta)+ sgn*flip(rr*sin(theta))))
        else
          d = cabs(pz - (rr*cos(theta) + sgn*flip(rr*sin(theta))))
        endif
        m_LastZ = (rr*cos(theta) + sgn*flip(rr*sin(theta)))
      else
        float x = real(pz)
        float y = imag(pz)
        if @disttype == 0
          d = abs(x-rr*cos(theta) + y-rr*sin(theta))
        else
          d = (abs(x-rr*cos(theta)) + abs(y-rr*sin(theta)))
        endif
        m_LastZ = x-rr*cos(theta) + flip(y-rr*sin(theta))
      endif
      return d
    endfunc
    
  default:
    title = "Folium Of Descartes"
   int param v_trapshapefoliumofdescartes
     caption = "Version (Trap Shape Folium Of Descartes)"
     default = 101
     hint = "This version parameter is used to detect when a change has been made to the formula that is incompatible with the previous version. When that happens, this field will reflect the old version number to alert you to the fact that an alternate rendering is being used."
     visible = @v_trapshapefoliumofdescartes < 101
   endparam
   bool param ptraps
     caption = "Use as Polar Traps"
     default = false
   endparam
   param disttype
     caption = "Distance type"
     default = 0
     enum = "Abs total" "Abs parts"
     visible = @ptraps
     hint = "The distance function must be positive. \
             The absolute value can be taken of the \
             whole function or of its individual parts."
   endparam
    float param a
      caption = "Polar parameter"
      default = 0.2
      hint = "Affects spread and scale of trap"
    endparam
    bool param sgn
      caption = "Conjugate transform"
      default = false
      visible = !@ptraps
    endparam
    param absval
      caption = "Absolute Value"
      default = false
      visible = !@ptraps
    endparam
  }
 


Constructor Summary
REB_TrapShapeFoliumOfDescartes()
           
REB_TrapShapeFoliumOfDescartes(Generic pparent)
          Constructor
 
Method Summary
 float Iterate(complex pz)
          Call this for each iteration being trapped.
 
Methods inherited from class common:TrapShape
GetColorChannel, GetTextureValue, GetTransformedPoint, Init, IterateSilent, SetThreshold
 
Methods inherited from class common:Generic
GetParent
 
Methods inherited from class Object
 

Constructor Detail

REB_TrapShapeFoliumOfDescartes

public REB_TrapShapeFoliumOfDescartes(Generic pparent)
Constructor


REB_TrapShapeFoliumOfDescartes

public REB_TrapShapeFoliumOfDescartes()
Method Detail

Iterate

public float Iterate(complex pz)
Call this for each iteration being trapped.

Overrides:
Iterate in class TrapShape